Boole's rule

In mathematics, Boole's rule, named after George Boole, is a method of numerical integration.

It approximates an integral:

${\displaystyle \int _{a}^{b}f(x)\,dx}$

by using the values of f at five equally spaced points:^[1]

${\displaystyle {\begin{aligned}&x_{0}=a\\&x_{1}=x_{1}+h\\&x_{2}=x_{1}+2h\\&x_{3}=x_{1}+3h\\&x_{4}=x_{1}+4h=b\end{aligned}}}$

It is expressed thus in Abramowitz and Stegun:^[2]

${\displaystyle \int _{x_{0}}^{x_{4}}f(x)\,dx={\frac {2h}{45}}{\bigl [}7f(x_{0})+32f(x_{1})+12f(x_{2})+32f(x_{3})+7f(x_{4}){\bigr ]}+{\text{error term}}}$

where the error term is

${\displaystyle -\,{\frac {8f^{(6)}(\xi )h^{7}}{945}}}$

for some number ⁠${\displaystyle \xi }$⁠ between ⁠${\displaystyle x_{0}}$⁠ and ⁠${\displaystyle x_{4}}$⁠ where 945 = 1 × 3 × 5 × 7 × 9.

It is often known as Bode's rule, due to a typographical error that propagated from Abramowitz and Stegun.^[3]

The following constitutes a very simple implementation of the method in Common Lisp which ignores the error term:

(defun integrate-booles-rule (f x1 x5)
  "Calculates the Boole's rule numerical integral of the function F in
   the closed interval extending from inclusive X1 to inclusive X5
   without error term inclusion."
  (declare (type (function (real) real) f))
  (declare (type real                   x1 x5))
  (let ((h (/ (- x5 x1) 4)))
    (declare (type real h))
    (let* ((x2 (+ x1 h))
           (x3 (+ x2 h))
           (x4 (+ x3 h)))
      (declare (type real x2 x3 x4))
      (* (/ (* 2 h) 45)
         (+ (*  7 (funcall f x1))
            (* 32 (funcall f x2))
            (* 12 (funcall f x3))
            (* 32 (funcall f x4))
            (*  7 (funcall f x5)))))))

In cases where the integration is permitted to extend over equidistant sections of the interval ${\displaystyle [a,b]}$, the composite Boole's rule might be applied. Given ${\displaystyle N}$ divisions, the integrated value amounts to:^[4]

$${\displaystyle \int _{x_{0}}^{x_{N}}f(x)\,dx={\frac {2h}{45}}\left(7(f(x_{0})+f(x_{N}))+32\left(\sum _{i\in \{1,3,5,\ldots ,N-1\}}f(x_{i})\right)+12\left(\sum _{i\in \{2,6,10,\ldots ,N-2\}}f(x_{i})\right)+14\left(\sum _{i\in \{4,8,12,\ldots ,N-4\}}f(x_{i})\right)\right)}$$

The following Common Lisp code implements the aforementioned formula:

(defun integrate-composite-booles-rule (f a b n)
  "Calculates the composite Boole's rule numerical integral of the
   function F in the closed interval extending from inclusive A to
   inclusive B across N subintervals."
  (declare (type (function (real) real) f))
  (declare (type real                   a b))
  (declare (type (integer 1 *)          n))
  (let ((h (/ (- b a) n)))
    (declare (type real h))
    (flet ((f[i] (i)
            (declare (type (integer 0 *) i))
            (let ((xi (+ a (* i h))))
              (declare (type real xi))
              (the real (funcall f xi)))))
      (* (/ (* 2 h) 45)
         (+ (*  7 (+ (f[i] 0) (f[i] n)))
            (* 32 (loop for i from 1 to (- n 1) by 2 sum (f[i] i)))
            (* 12 (loop for i from 2 to (- n 2) by 4 sum (f[i] i)))
            (* 14 (loop for i from 4 to (- n 4) by 4 sum (f[i] i))))))))

• Newton–Cotes formulas
• Simpson's rule
• Romberg's method

• Boole, George (1880) [1860]. A Treatise on the Calculus of Finite Differences (3rd ed.). Macmillan and Company.

• Davis, Philip J.; Polonsky, Ivan (1983) [June 1964]. "Chapter 25, eqn 25.4.14". In Abramowitz, Milton; Stegun, Irene Ann (eds.). Handbook of Mathematical Functions with Formulas, Graphs, and Mathematical Tables. Applied Mathematics Series. Vol. 55 (Ninth reprint with additional corrections of tenth original printing with corrections (December 1972); first ed.). Washington D.C.; New York: United States Department of Commerce, National Bureau of Standards; Dover Publications. p. 886. ISBN 978-0-486-61272-0. LCCN 64-60036. MR 0167642. LCCN 65-12253.

• Ubale, P. V. (2012). "Numerical Solution of Boole's Rule in Numerical Integration by Using General Quadrature Formula" (PDF). The Bulletin of Society for Mathematical Services and Standards. 2: 1–4. doi:10.18052/www.scipress.com/BSMaSS.2.1. Retrieved December 21, 2022.

• Weisstein, Eric W. "Boole's Rule". MathWorld.